В принципе, вроде нашел решение... :)))

Замечание к документу "Конечно, конечно. Но это "не решение" меня устраивает, а Вы найдите РЕШЕНИЕ - и поделитесь, не сочтите за труд." >>>

Тема: В принципе, вроде нашел решение... :)))

Создан:

Du ChAN 08/30/2002 08:42 AM

Папка:
03. Русские буквы и Notes, 04. Специфичное "русскому" Lotus Notes, 06. Разработка Notes-приложений

Тип сообщения:
Решение

Сообщение:
исходя из того что Windows это оконная ОС (масло-масленное), я нашел способ как определить открыт ли файл в другом окне...
принцип:
1.получаем список всех окон
2.ищем в заголовках окна название нашего файла
и если есть такое то файл редактируется(открыт)....
есть несколько НО - 1.не все приложения в заголовок выводят имя файла, напримел IE (но насколько я посмотрел-поэкпкрементировал все попавшиеся мне редакторы это делают); 2. необходимо ждать пока приложение откроется и откроет переданный нами файл (но здесь проше чем со способом проверки открытием файла, можно в таймауте секунд 15 поставить ежесекндную проверку на нахождения окна); 3.необходимо чтобы Ваше приложение не выводило ни в какие окна (в том числе и дочернии-диалоговые) в заголовок имя файла (иначе нахождение не вашего окна усложнится!!!); 4.в приложении редакторе может быть несколько окон в заголовках которых присутствует имя вашего файла (дочерние окна, MDI-интерфейс) и не всегда родительское окно (даже если поночалу в нем и есть имя файла(пример MDI)) будет идентифицировать сам файл (так что hWnd хранить нельзя а надо постоянно выбирать список окон или хранить все hWnd и проверять их на заголовок).
Вот... вроде текстовая часть описания закончена...
Теперь пример:
(это пример вывода ВСЕХ окон, для заточки под конкретные применения его придется править. Пример показывает только сам принцип работы с окнами...)
(сам принцип был взят с сайта: http://www.vbnet.ru/
исходный пример: http://www.vbnet.ru/faq/showtopic.asp?id=140)
это код кнопки на форме
на форме так же присутствует поле "WindowList"

Private Const mcGWCHILD = 5
Private Const mcGWHWNDNEXT = 2
Private Const mcGWLSTYLE = (-16)
Private Const mcWSVISIBLE = &H10000000
Private Const mconMAXLEN = 255

Declare Function apiGetClassName Lib "user32" Alias "GetClassNameA" (Byval Hwnd As Long, Byval lpClassname As String, Byval nMaxCount As Long) As Long
Declare Function apiGetDesktopWindow Lib "user32" Alias "GetDesktopWindow" () As Long
Declare Function apiGetWindow Lib "user32" Alias "GetWindow" (Byval Hwnd As Long, Byval wCmd As Long) As Long
Declare Function apiGetWindowLong Lib "user32" Alias "GetWindowLongA" (Byval Hwnd As Long, Byval nIndex As Long) As Long
Declare Function apiGetWindowText Lib "user32" Alias "GetWindowTextA" (Byval Hwnd As Long, Byval lpString As String, Byval aint As Long) As Long

Dim ws As notesUIWorkspace
Dim note As notesUIDocument

Sub Click(Source As Button)
Set ws = New notesUIWorkspace
Set note = ws.CurrentDocument

Call note.FieldSetText("WindowList", "")

Call fEnumWindows(apiGetDesktopWindow(), 0)
End Sub

Function fEnumWindows(Plngx As Long, Ur As Integer)
Dim lngx As Long, lngLen As Long
Dim lngStyle As Long, strCaption As String

'Return the first child to Desktop
lngx = apiGetWindow(Plngx, mcGWCHILD)
Do While Not lngx = 0
strCaption = fGetCaption(lngx)
If Len(strCaption) > 0 Then
lngStyle = apiGetWindowLong(lngx, mcGWLSTYLE)
'enum visible windows only
If lngStyle And mcWSVISIBLE Then
AddWin$ = String(Ur, "-")+"Class = " & fGetClassName(lngx) & " - Caption = " & fGetCaption(lngx)
OldList$ = note.FieldGetText("WindowList")
Call note.FieldSetText("WindowList",OldList$+Chr$(10)+AddWin$)
End If
End If
Call fEnumWindows(lngx, Ur+1)
lngx = apiGetWindow(lngx, mcGWHWNDNEXT)
Loop
End Function

Function fGetCaption(Hwnd As Long)
Dim strBuffer As String
Dim intCount As Integer
strBuffer = String$(mconMAXLEN - 1, 0)
intCount = apiGetWindowText(Hwnd, strBuffer, mconMAXLEN)
If intCount > 0 Then
fGetCaption = Left$(strBuffer, intCount)
End If
End Function

Function fGetClassName(Hwnd As Long)
Dim strBuffer As String
Dim intCount As Integer
strBuffer = String$(mconMAXLEN - 1, 0)
intCount = apiGetClassName(Hwnd, strBuffer, mconMAXLEN)
If intCount > 0 Then
fGetClassName = Left$(strBuffer, intCount)
End If
End Function